一、自治事務(wù)使用情況

無(wú)法回滾的審計(jì) ： 一般情況下利用觸發(fā)器禁止某些對(duì)表的更新等操作時(shí)，若記錄日志，則觸發(fā)器最后拋出異常時(shí)會(huì)造成日志回滾。利用自治事務(wù)可防止此點(diǎn)。 

避免變異表： 即在觸發(fā)器中操作觸發(fā)此觸發(fā)器的表 

在觸發(fā)器中使用ddl 寫(xiě)數(shù)據(jù)庫(kù)：對(duì)數(shù)據(jù)庫(kù)有寫(xiě)操作（insert、update、delete、create、alter、commit）的存儲(chǔ)過(guò)程或函數(shù)是無(wú)法簡(jiǎn)單的用sql來(lái)調(diào)用的，此時(shí)可以將其設(shè)為自治事務(wù)，從而避免ora-14552（無(wú)法在一個(gè)查詢或dml中執(zhí)行ddl、commit、rollback）、ora-14551（無(wú)法在一個(gè)查詢中執(zhí)行dml操作）等錯(cuò)誤。需要注意的是函數(shù)必須有返回值，但僅有in參數(shù)（不能有out或in/out參數(shù)）。 

開(kāi)發(fā)更模塊化的代碼： 在大型開(kāi)發(fā)中，自治事務(wù)可以將代碼更加模塊化，失敗或成功時(shí)不會(huì)影響調(diào)用者的其它操作，代價(jià)是調(diào)用者失去了對(duì)此模塊的控制，并且模塊內(nèi)部無(wú)法引用調(diào)用者未提交的數(shù)據(jù)。 

二、Oracle 自制事務(wù) 

Oracle 自制事務(wù)是指的存儲(chǔ)過(guò)程和函數(shù)可以自己處理內(nèi)部事務(wù)不受外部事務(wù)的影響，用pragma autonomous_transaction來(lái)聲明，要?jiǎng)?chuàng)建一個(gè)自治事務(wù)，您必須在匿名塊的最高層或者存儲(chǔ)過(guò)程、函數(shù)、數(shù)據(jù)包或觸發(fā)的定義部分中，使用PL/SQL中的PRAGMA AUTONOMOUS_TRANSACTION語(yǔ)句。在這樣的模塊或過(guò)程中執(zhí)行的SQL語(yǔ)句都是自治的。 

結(jié)束一個(gè)自治事務(wù)必須提交一個(gè)commit、rollback或執(zhí)行ddl，否則會(huì)產(chǎn)生Oracle錯(cuò)誤ORA-06519: active autonomous transaction detected and rolled back 。 

三、實(shí)例 

------------------------------------------------------------------------- 
-- 存儲(chǔ)過(guò)程名：P_DTMS_UPDATE_SAP 
-- 插入數(shù)據(jù)到T_DATA_DTMS_TAX_EXPORTTOSAP中 
-- 自治事務(wù)（pragma autonomous_transaction） 
-- 2012-12-28 
------------------------------------------------------------------------- 
create or replace procedure P_DTMS_UPDATE_SAP( 
i_pkvalue in number, 
i_opcontent_ori in VARCHAR2, 
i_opcontent_dest in VARCHAR2, 
i_source in varchar2 
) 
is 
pragma autonomous_transaction; 
begin 
INSERT INTO T_DATA_DTMS_TAX_EXPORTTOSAP(ID, DTMS_TAX_INVOICE_ID, OPERATE_TYPE, EXPORT_TO_SAP_ORI, EXPORT_TO_SAP_DEST, OPERATE_TIME, SOURCE) 
    VALUES(SEQ_DATA_DTMS_TAX_EXPORTTOSAP.NEXTVAL,i_pkvalue,'update',i_opcontent_ori,i_opcontent_dest,sysdate, i_source); 
commit; 
end; 
------------------------------------------------------------------------- 
-- 觸發(fā)器名稱(chēng)：TRG_INVOICE_EXPORTTOSAP_MODIFY 
-- 當(dāng)表T_DTMS_TAX_INVOICE做更新操作時(shí)觸發(fā)，用于對(duì)EXPORT_TO_SAP標(biāo)志位做將1改為0時(shí)，拋出異常，回滾修改，即：不允許將EXPORT_TO_SAP從1改為0 
-- 2012-12-28 
------------------------------------------------------------------------- 
create or replace trigger "TRG_INVOICE_EXPORTTOSAP_MODIFY" 
  after update 
  on T_DTMS_TAX_INVOICE 
  for each row 
declare v_pkvalue NUMBER(20); 
        v_opcontent_ori VARCHAR2(50);--修改前的值 
        v_opcontent_dst VARCHAR2(50);--修改后的值 
begin 
  v_pkvalue := :new.id; 
  case when updating then 
    v_opcontent_ori := :old.EXPORT_TO_SAP; 
    v_opcontent_dst := :new.EXPORT_TO_SAP; 
    if v_opcontent_ori = 1 and v_opcontent_dst = 0 then 
      P_DTMS_UPDATE_SAP(v_pkvalue,v_opcontent_ori,v_opcontent_dst,'invoice');--自治事務(wù)，調(diào)用這個(gè)過(guò)程的時(shí)候它就會(huì)獨(dú)立于調(diào)用它的父事務(wù)進(jìn)行操作 
      RAISE_APPLICATION_ERROR(-20100, 'Cannot Modify T_DTMS_TAX_INVOICE.EXPORT_TO_SAP From 1 To 0.');--拋出異常，RAISE_APPLICATION_ERROR(num,msg)，num在-20000到-20999之間，msg寫(xiě)你希望拋出的異常。 
    end if; 
  end case; 
end;